# Udrulning via Terraform

Følgende skal tilføjes til dit miljø sammen med enhver anden standardkonfiguration, du udruller via Terraform.

### Hosts

To [Host/Backend](https://docs.netacea.com/dk/netacea-plugin-information/fastly/installation-and-configuration/..#host) variabler skal tilføjes til `fastly_service_vcl` ressourcen:

```
  # Netacea backends 
  backend {
    name = "MitSvc"
    address = "geo-mitigations.netacea.net"
    use_ssl = true
    override_host = "geo-mitigations.netacea.net"
    ssl_cert_hostname = "geo-mitigations.netacea.net"
    ssl_sni_hostname = "geo-mitigations.netacea.net"
    port = "443"
    request_condition = "Netacea Forward Request"
  }

  backend {
    name = "CaptchaAssets"
    address = "assets.ntcacdn.net"
    use_ssl = true
    override_host = "assets.ntcacdn.net"
    ssl_cert_hostname = "assets.ntcacdn.net"
    ssl_sni_hostname = "assets.ntcacdn.net"
    port = "443"
    request_condition = "Netacea Forward Request"
  }

  # Prevent Netacea backends from being selected as default
  condition {
    name = "Netacea Forward Request"
    statement = "false"
    type = "REQUEST"
  }
```

### Dictionary

En dictionary skal tilføjes til `fastly_service_vcl` ressourcen:

```
 # Defines the Netacea dictionary
 dictionary {
    name = "netacea_edge_config"
  }
```

For at udfylde variablerne i dictionaryen, brug `fastly_service_dictionary` ressourcen:

{% hint style="info" %}
Hvis du ikke har drøftet avanceret konfiguration med Netacea, behøver ingen variabler at blive defineret.
{% endhint %}

```
# Define the config values
  items = {
    api_key: var.netacea_api_key
    secret_key: var.netacea_secret_key
    encryption_key: var.netacea_encryption_key
    integration_mode: "MITIGATE"
    cookie_name: "cookieName"
    captcha_cookie_name: "cCookieName"
  }

  # Find the netacea_edge_config dictionary
  for_each = {
    for d in fastly_service_vcl.example.dictionary : d.name => d if d.name == "netacea_edge_config"
  }

  # Link config values to the netacea_edge_config dictionary
  service_id = fastly_service_vcl.example.id
  dictionary_id = each.value.dictionary_id

  # Declare that dictionary values must be managed by Terraform.
  # Changes to this dictionary applied in any other way will be overwritten.
  manage_items = true

```

For mere information om `fastly_service_dictionary` ressourcen, se [Fastly Provider docs](https://registry.terraform.io/providers/fastly/fastly/latest/docs/resources/service_dictionary_items)

Du skal også sikre, at følgende variabler er defineret i dit miljø:

```
variable "netacea_api_key" {
  description = "Defines which Netacea Datastream is called"
  type = string
  sensitive = true
}

variable "netacea_secret_key" {
  description = "Netacea Datastream Secret"
  type = string
  sensitive = true
}

variable "netacea_encryption_key" {
  description = "Encrypts Netacea cookie"
  type = string
  sensitive = true
}
```

Variablerne skal udfyldes med værdierne, der findes på din tilknyttede [Netacea Datastream](https://docs.netacea.com/dk/netacea-plugin-information/accessing-your-integration-settings). Se [her](https://developer.hashicorp.com/terraform/language/values/variables) for mere information om indstilling af værdier.

### VCL Snippets

Netacea vil levere 7 [VCL snippets](https://docs.netacea.com/dk/netacea-plugin-information/fastly/installation-and-configuration/..#vcl-snippets) separat, filerne skal tilføjes til den relevante mappe, som gemmer dine VCL snippets.

Du skal også referere til disse i `fastly_service_vcl` ressourcen:

```
snippet {
    name     = "netacea_integration_init"
    type     = "init"
    content  = file("./netacea/netacea_init.vcl")
    priority = 45
  }

  snippet {
    name     = "netacea_integration_recv"
    type     = "recv"
    content  = file("./netacea/netacea_recv.vcl")
    priority = 45
  }

  snippet {
    name     = "netacea_integration_recv_configure"
    type     = "recv"
    content  = file("./netacea/netacea_recv_configure.vcl")
    priority = 46
  }

  snippet {
    name     = "netacea_integration_error"
    type     = "error"
    content  = file("./netacea/netacea_error.vcl")
    priority = 45
  }

  snippet {
    name     = "netacea_integration_deliver"
    type     = "deliver"
    content  = file("./netacea/netacea_deliver.vcl")
    priority = 45
  }
  
    snippet {
    name     = "netacea_integration_pass"
    type     = "pass"
    content  = file("./netacea/netacea_pass.vcl")
    priority = 45
  }
  
    snippet {
    name     = "netacea_integration_miss"
    type     = "miss"
    content  = file("./netacea/netacea_miss.vcl")
    priority = 45
  }
  
```

{% hint style="info" %}
Opdater hvert content-felt med mappen, hvor Netacea VCL'erne er blevet gemt.
{% endhint %}

## Udrulning

Du er nu i stand til at udrulle Netacea-integrationen.

For mere information om `fastly_service_vcl` ressourcen, se [Fastly provider docs](https://registry.terraform.io/providers/fastly/fastly/latest/docs/resources/service_vcl).