# Bereitstellung über Terraform

Die folgenden Elemente sollten neben jeder anderen Standardkonfiguration, die Sie über Terraform bereitstellen, zu Ihrer Umgebung hinzugefügt werden.

### Hosts

Zwei [Host/Backend](https://docs.netacea.com/de/netacea-plugin-informationen/fastly/installation-and-configuration/..#host)-Variablen müssen zur `fastly_service_vcl`-Ressource hinzugefügt werden:

```
  # Netacea backends 
  backend {
    name = "MitSvc"
    address = "geo-mitigations.netacea.net"
    use_ssl = true
    override_host = "geo-mitigations.netacea.net"
    ssl_cert_hostname = "geo-mitigations.netacea.net"
    ssl_sni_hostname = "geo-mitigations.netacea.net"
    port = "443"
    request_condition = "Netacea Forward Request"
  }

  backend {
    name = "CaptchaAssets"
    address = "assets.ntcacdn.net"
    use_ssl = true
    override_host = "assets.ntcacdn.net"
    ssl_cert_hostname = "assets.ntcacdn.net"
    ssl_sni_hostname = "assets.ntcacdn.net"
    port = "443"
    request_condition = "Netacea Forward Request"
  }

  # Prevent Netacea backends from being selected as default
  condition {
    name = "Netacea Forward Request"
    statement = "false"
    type = "REQUEST"
  }
```

### Dictionary

Ein Dictionary muss zur `fastly_service_vcl`-Ressource hinzugefügt werden:

```
 # Defines the Netacea dictionary
 dictionary {
    name = "netacea_edge_config"
  }
```

Um die Variablen innerhalb des Dictionarys zu befüllen, verwenden Sie die `fastly_service_dictionary`-Ressource:

{% hint style="info" %}
Falls Sie keine erweiterte Konfiguration mit Netacea besprochen haben, müssen keine Variablen definiert werden.
{% endhint %}

```
# Define the config values
  items = {
    api_key: var.netacea_api_key
    secret_key: var.netacea_secret_key
    encryption_key: var.netacea_encryption_key
    integration_mode: "MITIGATE"
    cookie_name: "cookieName"
    captcha_cookie_name: "cCookieName"
  }

  # Find the netacea_edge_config dictionary
  for_each = {
    for d in fastly_service_vcl.example.dictionary : d.name => d if d.name == "netacea_edge_config"
  }

  # Link config values to the netacea_edge_config dictionary
  service_id = fastly_service_vcl.example.id
  dictionary_id = each.value.dictionary_id

  # Declare that dictionary values must be managed by Terraform.
  # Changes to this dictionary applied in any other way will be overwritten.
  manage_items = true

```

Weitere Informationen zur `fastly_service_dictionary`-Ressource finden Sie in der [Fastly Provider-Dokumentation](https://registry.terraform.io/providers/fastly/fastly/latest/docs/resources/service_dictionary_items)

Sie müssen außerdem sicherstellen, dass die folgenden Variablen in Ihrer Umgebung definiert sind:

```
variable "netacea_api_key" {
  description = "Defines which Netacea Datastream is called"
  type = string
  sensitive = true
}

variable "netacea_secret_key" {
  description = "Netacea Datastream Secret"
  type = string
  sensitive = true
}

variable "netacea_encryption_key" {
  description = "Encrypts Netacea cookie"
  type = string
  sensitive = true
}
```

Die Variablen müssen mit den Werten befüllt werden, die in Ihrem zugehörigen [Netacea Datastream](https://docs.netacea.com/de/netacea-plugin-informationen/accessing-your-integration-settings) zu finden sind. Weitere Informationen zum Festlegen von Werten finden Sie [hier](https://developer.hashicorp.com/terraform/language/values/variables).

### VCL-Snippets

Netacea stellt 7 [VCL-Snippets](https://docs.netacea.com/de/netacea-plugin-informationen/fastly/installation-and-configuration/..#vcl-snippets) separat bereit. Die Dateien sollten dem entsprechenden Verzeichnis hinzugefügt werden, in dem Ihre VCL-Snippets gespeichert sind.

Sie müssen diese auch in der `fastly_service_vcl`-Ressource referenzieren:

```
snippet {
    name     = "netacea_integration_init"
    type     = "init"
    content  = file("./netacea/netacea_init.vcl")
    priority = 45
  }

  snippet {
    name     = "netacea_integration_recv"
    type     = "recv"
    content  = file("./netacea/netacea_recv.vcl")
    priority = 45
  }

  snippet {
    name     = "netacea_integration_recv_configure"
    type     = "recv"
    content  = file("./netacea/netacea_recv_configure.vcl")
    priority = 46
  }

  snippet {
    name     = "netacea_integration_error"
    type     = "error"
    content  = file("./netacea/netacea_error.vcl")
    priority = 45
  }

  snippet {
    name     = "netacea_integration_deliver"
    type     = "deliver"
    content  = file("./netacea/netacea_deliver.vcl")
    priority = 45
  }
  
    snippet {
    name     = "netacea_integration_pass"
    type     = "pass"
    content  = file("./netacea/netacea_pass.vcl")
    priority = 45
  }
  
    snippet {
    name     = "netacea_integration_miss"
    type     = "miss"
    content  = file("./netacea/netacea_miss.vcl")
    priority = 45
  }
  
```

{% hint style="info" %}
Aktualisieren Sie jedes der content-Felder mit dem Verzeichnis, in dem die Netacea-VCLs gespeichert wurden.
{% endhint %}

## Bereitstellung

Sie können nun die Netacea-Integration bereitstellen.

Weitere Informationen zur `fastly_service_vcl`-Ressource finden Sie in der [Fastly Provider-Dokumentation](https://registry.terraform.io/providers/fastly/fastly/latest/docs/resources/service_vcl).